리습 강좌 - 두점 사이를 지나는 모든 오브젝트의 교차점 리턴함수.

본 강좌는 아키오피스(김희태)에 의해 만들어 졌으며 어떠한 웹이나
출판물에 아키오피스(김희태)의 동의없이 올리는 것을 허락하지 않습니다.

 

두 점과 두점사이에 존재하는 오브젝트와의 교차점 리스트를 리턴하는 함수 입니다.

김판섭 님이 소스를 제공해 주셨고 제가 리습함수로써 사용할수 있도록 수정했습니다.

 

(vl-Get-Int-Pt  첫번째 point , 두번째 point) => 교차점 리스트 리턴. 교차점이 없으면 Nil 리턴.

(vl-Get-Int-Pt point1 point2)


=> ((54787.5 20479.5 0.0) (56656.1 20813.8 0.0) 
(59038.6 21240.0 0.0) (60627.4 21524.2 0.0) (61564.7 21691.8 0.0) (64103.6 22146.0 0.0)
(68404.1 22915.3 0.0) (69224.1 23062.0 0.0))

코드 

  (defun kht:list->safearray (lst datatype)
    (vlax-safearray-fill
      (vlax-make-safearray
        (eval datatype)
        (cons 0 (1- (length lst)))
      )
      lst
    )
  )

(defun vl-Get-Int-Pt (FirstPoint SecondPoint /
                             acadDocument mSpace SSetName SSets SSet reapp ex obj
                             Baseline  )
  (vl-load-com)
  (setq acadDocument (vla-get-ActiveDocument (vlax-get-acad-object)))
  (setq mSpace (vla-get-ModelSpace acadDocument))
  (setq SSetName "MySSet")
  (setq SSets (vla-get-SelectionSets acadDocument))

  (if (vl-catch-all-error-p
        (vl-catch-all-apply 'vla-add (list SSets SSetName))
      )
    (vla-clear (vla-Item SSets SSetName))
  ) 
  
  (setq SSet (vla-Item SSets SSetName))

  (setq Baseline (vla-Addline mspace (vlax-3d-point FirstPoint) (vlax-3d-point SecondPoint)))
 
  (vla-SelectByPolygon
    SSet
    acSelectionSetFence
    (kht:list->safearray (append FirstPoint SecondPoint) 'vlax-vbdouble)
  )
  
  (vlax-for obj sset
    (if (setq ex (kht-intersect (vlax-vla-object->ename BaseLine) (vlax-vla-object->ename obj)))
      (setq reapp (append reapp ex))
    )
  )

  (vla-delete BaseLine)

  (setq	reapp (vl-sort reapp '(lambda (e1 e2) (< (car e1) (car e2)))))
  
  reapp
)
설명 

  ;; 이 함수는 리스트를 safearray 로 전환하여 리턴하는 함수입니다.
  ;; activex 함수는 배열 또는 vb 데이타 형식만 적용되기 때문입니다.
  ;; 매개변수 datatype 은 vlax-vbvariant , vlax-vbstring , vlax-vbinteger 등이 여러 형이 올수 있습니다.
  ;; 당연히 리스트는 datatype 형과 일치해야 됩니다.

  (defun kht:list->safearray (lst datatype)
    (vlax-safearray-fill
      (vlax-make-safearray
        (eval datatype)
        (cons 0 (1- (length lst)))
      )
      lst
    )
  )

(defun vl-Get-Int-Pt (FirstPoint SecondPoint /
                             acadDocument mSpace SSetName SSets SSet reapp ex obj
                             Baseline  )
  (vl-load-com)
  (setq acadDocument (vla-get-ActiveDocument (vlax-get-acad-object)))
  (setq mSpace (vla-get-ModelSpace acadDocument))
  (setq SSetName "MySSet")
  ;; SelectionSet 컬렉션을 얻는다.
  (setq SSets (vla-get-SelectionSets acadDocument))
  ;; SelectionSet "MySSet" 을 초기화 한다.
  ;; 만약 "MySSet" 이 있는데 추가 하면 에러가 나므로 에러를 잡아 "MySSet" 를 비운다.
  (if (vl-catch-all-error-p
        (vl-catch-all-apply 'vla-add (list SSets SSetName))
      )
    (vla-clear (vla-Item SSets SSetName))
  ) 
  ;; SelectionSet "MySSet" 을 얻고.
  (setq SSet (vla-Item SSets SSetName))
  ;; 두 포인트를 끝점으로 하는 가상의 라인을 만든다.
  (setq Baseline (vla-Addline mspace (vlax-3d-point FirstPoint) (vlax-3d-point SecondPoint)))
  ;; acSelectionSetFence 로써 두점 사이의 오브젝트를 선택한다.
  (vla-SelectByPolygon
    SSet
    acSelectionSetFence
    (kht:list->safearray (append FirstPoint SecondPoint) 'vlax-vbdouble)
    ;; 만약 임의의 객체 라든지 임의의 레이어를 가진 객체만 선별적으로 선택하고 싶다면.
    ;; 바로 여기에 SelectionSet fillter 옾션을 주면 된다.
  )
  ;; 선택된 각각의 오브젝트와 가상의 라인이 교차한다면 kht-intersect 함수로 교차점을 얻는다.
  (vlax-for obj sset
    (if (setq ex (kht-intersect (vlax-vla-object->ename BaseLine) (vlax-vla-object->ename obj)))
      (setq reapp (append reapp ex))
    )
  )
  ;; 가상의 라인을 삭제 한다.
  (vla-delete BaseLine)
  ;; 교차점들을 x 좌표를 기준으로 오름차순으로 정열한다.
  (setq	reapp (vl-sort reapp '(lambda (e1 e2) (< (car e1) (car e2)))))
  ;; 교차점들을 리턴한다.
  reapp
)